Sconstruct

#!/usr/bin/env python
import os
from glob import glob
from SCons import SCons
from SCons.Environment import Environment

env = SConscript("godot-cpp/SConstruct")

def GlobRecursive(pattern, node='.'):
    results = []
    for f in Glob(str(node) + '/*', source=True):
        if type(f) is SCons.Node.FS.Dir:
            results += GlobRecursive(pattern, f)
    results += Glob(str(node) + '/' + pattern, source=True)
    return results

# For reference:
# - CCFLAGS are compilation flags shared between C and C++
# - CFLAGS are for C-specific compilation flags
# - CXXFLAGS are for C++-specific compilation flags
# - CPPFLAGS are for pre-processor flags
# - CPPDEFINES are for pre-processor defines
# - LINKFLAGS are for linking flags

# tweak this if you want to use different folders, or more folders, to store your source code in.
env.Append(CPPPATH=["includes", "godot-cpp/include", "godot-cpp/include/godot_cpp", "godot-cpp/", "godot-cpp/gen/include", "godot-cpp/gen/include/godot_cpp", "godot-cpp/gdextension"])
sources = GlobRecursive("*.cpp", "src/")

env.Append(CPPFLAGS=["-DGODOT_EXT=1"])

if env["platform"] == "macos":
    library = env.SharedLibrary(
        "bin/libcavernfall.{}.{}.framework/libcavernfall.{}.{}".format(
            env["platform"], env["target"], env["platform"], env["target"]
        ),
        source=sources,
    )
elif env["platform"] == "ios":
    if env["ios_simulator"]:
        library = env.StaticLibrary(
            "bin/libcavernfall.{}.{}.simulator.a".format(env["platform"], env["target"]),
            source=sources,
        )
    else:
        library = env.StaticLibrary(
            "bin/libcavernfall.{}.{}.a".format(env["platform"], env["target"]),
            source=sources,
        )
else:
    library = env.SharedLibrary(
        "bin/libcavernfall{}{}".format(env["suffix"], env["SHLIBSUFFIX"]),
        source=sources,
    )

Default(library)