Software_2016/build.gradle at master · EasternEdgeRobotics/Software_2016 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
plugins {
    id 'com.zoltu.kotlin' version '1.0.2'
}

apply plugin: 'java'
apply plugin: 'application'
apply plugin: com.easternedgerobotics.gradle.MultipleStartScripts
apply plugin: 'jacoco'
apply plugin: 'checkstyle'

applicationDefaultJvmArgs = [
    '-Xloggc:gc.log', '-XX:+PrintGCApplicationStoppedTime', '-XX:+PrintGCTimeStamps'
]
applicationName = 'topside'
version = '9.0.0'
mainClassName = 'com.easternedgerobotics.rov.Topside'
sourceCompatibility = JavaVersion.VERSION_1_8

checkstyle {
    toolVersion = '6.18'
}

jacoco {
    toolVersion = '0.7.5.201505241946'
}

repositories {
    jcenter()
}

dependencies {
    compile 'com.fasterxml.jackson.core:jackson-databind:2.5.3'
    compile 'com.neuronrobotics:nrjavaserial:3.11.0'
    compile 'com.pi4j:pi4j-core:1.0'
    compile 'commons-cli:commons-cli:1.3.1'
    compile 'io.reactivex:rxjava:1.0.12'
    compile 'io.reactivex:rxjavafx:0.0.5'
    compile 'javax.inject:javax.inject:1'
    compile 'net.java.jinput:jinput:2.0.6'
    compile 'org.jetbrains.kotlin:kotlin-stdlib:1.0.2'
    compile 'org.tinylog:tinylog:1.0.3'
    compile 'rxbroadcast:rxbroadcast:0.0.4'
    testCompile 'junit:junit:4.12'
    testCompile 'org.mockito:mockito-core:2.0.53-beta'
}

allprojects {
    gradle.projectsEvaluated {
        tasks.withType(JavaCompile) {
            options.compilerArgs << '-Xlint:unchecked' << '-Xdiags:verbose'
        }
    }
}

test {
    testLogging {
        exceptionFormat = 'full'
        showStandardStreams = true
        events 'passed', 'skipped', 'failed'
    }
}

multipleStartScripts {
    mainClasses = [
        'picamera-a': 'com.easternedgerobotics.rov.PicameraA',
        'picamera-b': 'com.easternedgerobotics.rov.PicameraB',
        'rov': 'com.easternedgerobotics.rov.Rov',
        'topside': 'com.easternedgerobotics.rov.Topside',
    ]
}

task testJar(type: Jar) {
    from sourceSets.test.output + sourceSets.main.output
    from(configurations.testCompile.collect { it.isDirectory() ? it : zipTree(it) }) {
        exclude 'META-INF/**'
    }

    classifier 'tests'
    description 'Assembles a jar archive containing the test classes.'
    group 'verification'
}