[General]: global-treesit-auto-mode extremely slow in emacs-plus 30.2

[cmore-zz]

Issue description

Took me a bit to track this one down, ended up using "kill -USR2 {emacs-pid}" to get the lisp stacktrace.

The issue is that treesit-language-available-p seems to have gotten much slower in emacs-plus 30.2 (although it's possible it's a macOS change). Granted, one can turn global-treesit-auto-mode off as a work-around. Because treesit-available-p gets called on every file open when global-treesit-auto-mode is enabled, it makes emacs feel very slow, and affects various other commands that generate buffers that set a mode that treesit might support.

I (with LLM) hacked around it by adding a two level cache (one for per-session mtimes of library files, another for enabled and source mtimes.

   (defvar my/treesit-available-cache (make-hash-table :test #'equal)
     "Persistent cache mapping language symbols to t/nil.")

   (defvar my/treesit-libfile-mtime-cache (make-hash-table :test #'equal)
     "Ephemeral cache mapping language symbols to last-known grammar mtime.")

   (defvar my/treesit-available-persist-file
     (expand-file-name "treesit-available-cache.el" user-emacs-directory)
     "File to persist Tree-sitter availability cache.")

   (defun my/load-treesit-cache ()
     "Load persistent Tree-sitter availability cache from disk."
     (when (file-readable-p my/treesit-available-persist-file)
       (with-temp-buffer
         (insert-file-contents my/treesit-available-persist-file)
         (let ((data (read (current-buffer))))
           (when (hash-table-p data)
             (setq my/treesit-available-cache data))))))

   (defun my/save-treesit-cache ()
     "Save the Tree-sitter availability cache to disk."
     (with-temp-file my/treesit-available-persist-file
       (let ((print-length nil)
             (print-level nil))
         (prin1 my/treesit-available-cache (current-buffer)))))

   (defun my/treesit-get-libfile-mtime (lang)
     "Return the mtime of the Tree-sitter grammar file for LANG, or nil if not found."
     (let ((libfile (ignore-errors (treesit--lib-file lang))))
       (when (and libfile (file-exists-p libfile))
         (nth 5 (file-attributes libfile))))) ;; mtime

   (advice-add 'treesit-language-available-p :around
               (lambda (orig-fn &rest args)
                 (let* ((lang (car args))
                        (current-mtime (my/treesit-get-libfile-mtime lang))
                        (cached-mtime (gethash lang my/treesit-libfile-mtime-cache))
                        (cached-result (gethash lang my/treesit-available-cache)))
                   ;; Check if mtime changed during this session
                   (if (and cached-result
                            (equal cached-mtime current-mtime))
                       cached-result
                     (let ((result (apply orig-fn args)))
                       (when current-mtime
                         (puthash lang current-mtime my/treesit-libfile-mtime-cache))
                       (puthash lang result my/treesit-available-cache)
                       result)))))

   (add-hook 'emacs-startup-hook #'my/load-treesit-cache)
   (add-hook 'kill-emacs-hook #'my/save-treesit-cache)   

[leaferiksen]

Treesit-auto is almost always unneeded these days, and I am almost certain that putting in the effort needed to keep it working is probably a waste of time.

(use-package treesit-langs :ensure t :vc (:url "https://github.com/emacs-tree-sitter/treesit-langs"))
(setq major-mode-remap-alist '((css-mode . css-ts-mode)
							   (dockerfile-mode . dockerfile-ts-mode)
							   (mhtml-mode . html-ts-mode)
							   (javascript-mode . js-ts-mode)
							   (json-mode . json-ts-mode)
							   (typescript-mode . typescript-ts-mode)
							   (yaml-mode . yaml-ts-mode)))

in my experience this has been a drop-in replacement, and requires no slow/unreliable background processes like treesit-auto.

[matthemsteger]

I don't think this is related to MacOS or this distribution. I had the same problem on my linux box and got rid of treesit-auto. It is no longer truly needed and was making things much slower in a lot of cases.

Here is what I use for example

(use-package treesit
  :preface
  (defun my--setup-install-grammars ()
    "Install Tree-sitter grammars if they are absent."
    (interactive)
    (dolist (grammar
             '((css . ("https://github.com/tree-sitter/tree-sitter-css" "v0.20.0"))
               (go . ("https://github.com/tree-sitter/tree-sitter-go" "v0.20.0"))
               (html . ("https://github.com/tree-sitter/tree-sitter-html" "v0.20.1"))
               (javascript . ("https://github.com/tree-sitter/tree-sitter-javascript" "v0.20.1" "src"))
               (json . ("https://github.com/tree-sitter/tree-sitter-json" "v0.20.2"))
               (markdown . ("https://github.com/ikatyang/tree-sitter-markdown" "v0.7.1"))
               (python . ("https://github.com/tree-sitter/tree-sitter-python" "v0.20.4"))
               (rust . ("https://github.com/tree-sitter/tree-sitter-rust" "v0.21.2"))
               (toml . ("https://github.com/tree-sitter/tree-sitter-toml" "v0.5.1"))
               (tsx . ("https://github.com/tree-sitter/tree-sitter-typescript" "v0.20.3" "tsx/src"))
               (typescript . ("https://github.com/tree-sitter/tree-sitter-typescript" "v0.20.3" "typescript/src"))
               (yaml . ("https://github.com/ikatyang/tree-sitter-yaml" "v0.5.0"))
	       (wgsl . ("https://github.com/szebniok/tree-sitter-wgsl" "master"))))
      (add-to-list 'treesit-language-source-alist grammar)
      ;; Only install `grammar' if we don't already have it
      ;; installed. However, if you want to *update* a grammar then
      ;; this obviously prevents that from happening.
      (unless (treesit-language-available-p (car grammar))
        (treesit-install-language-grammar (car grammar)))))
  (dolist (mapping
           '((python-mode . python-ts-mode)
             (css-mode . css-ts-mode)
             (typescript-mode . typescript-ts-mode)
             (js2-mode . js-ts-mode)
             (bash-mode . bash-ts-mode)
             (conf-toml-mode . toml-ts-mode)
             (go-mode . go-ts-mode)
             (css-mode . css-ts-mode)
             (json-mode . json-ts-mode)
             (js-json-mode . json-ts-mode)))
    (add-to-list 'major-mode-remap-alist mapping))
  :config
  (my--setup-install-grammars))