jsonlt.org/Justfile at main · jsonlt/jsonlt.org · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
set shell := ['uv', 'run', '--frozen', 'bash', '-euxo', 'pipefail', '-c']
set unstable
set positional-arguments

project := "jsonlt-org"
pnpm := "pnpm exec"

# List available recipes
default:
  @just --list

# Build the site
build:
  pnpm build

# Clean build artifacts
clean:
  rm -rf dist .astro

# Deploy to production
deploy:
  {{pnpm}} wrangler deploy

# Deploy to preview environment
deploy-preview pr_number:
  {{pnpm}} wrangler deploy --env preview --name jsonlt-website-preview-pr-{{pr_number}}

# Start development server
dev:
  pnpm dev

# Format code
format:
  {{pnpm}} biome format --write .

# Fix code issues
fix:
  {{pnpm}} biome check --write .

# Install all dependencies (Python + Node.js)
install: install-node install-python

# Install only Node.js dependencies
install-node:
  #!/usr/bin/env bash
  pnpm install --frozen-lockfile

# Install pre-commit hooks
install-prek:
  prek install

# Install only Python dependencies
install-python:
  #!/usr/bin/env bash
  uv sync --frozen

# Run all linters
lint: lint-markdown lint-prose lint-web

# Lint Markdown files
lint-markdown:
  {{pnpm}} markdownlint-cli2 "**/*.md"

# Lint prose in documentation
lint-prose:
  vale src/**/*.md

# Lint web files (CSS, HTML, JS, JSON)
lint-web:
  {{pnpm}} biome check .

# Run pre-commit hooks on changed files
prek:
  prek

# Run pre-commit hooks on all files
prek-all:
  prek run --all-files

# Preview the built site locally
preview:
  pnpm preview

# Sync Vale styles and dictionaries
vale-sync:
  vale sync