[Event Request] Codeunit 80 "Sales-Post" - Procedure SyncSurPlusItemTracking

[Mariangela-DeMaio-EOS]

Why do you need this change?

Hi,
i need an event at the end of procedure "SyncSurPlusItemTracking" in the Codeunit 80 "Sales-Post" to skip the execution of the "ModifyAll".

We need the event because we have an app that creates reservation entries of type Surplus, but the standard procedure "SyncSurPlusItemTracking" zeroes out the "Qty. to Handle (Base)" and "Qty. to Invoice (Base)" on these entries.
This causes an error when posting the warehouse shipment.
Our app has its logic to decide when skip the execution of "ModifyAll".

Below is the standard procedure code:

`

           local procedure SyncSurPlusItemTracking(SalesHeader: Record "Sales Header"; SalesLine: Record "Sales Line")
var
    Location2: Record Location;
    ReservEntry: Record "Reservation Entry";
    TempTrackingSpecification2: Record "Tracking Specification" temporary;
    TempWarehouseActivityLine: Record "Warehouse Activity Line" temporary;
    WarehouseAvailabilityMgt: Codeunit "Warehouse Availability Mgt.";
    QtyReservedForCurrLine: Decimal;
    SurplusQtyToHandle: Decimal;
begin
    if not SalesHeader.Ship then
        exit;
    if not (SalesHeader."Document Type" in [SalesHeader."Document Type"::Invoice, SalesHeader."Document Type"::Order]) then
        exit;

    if (SalesLine."Location Code" = '') or
       not Location2.Get(SalesLine."Location Code") or
       not Location2."Require Shipment"
    then
        exit;

    TempTrackingSpecification2.SetSourceFromSalesLine(SalesLine);
    QtyReservedForCurrLine := Abs(WarehouseAvailabilityMgt.CalcLineReservedQtyOnInvt(
        TempTrackingSpecification2."Source Type", TempTrackingSpecification2."Source Subtype", TempTrackingSpecification2."Source ID", TempTrackingSpecification2."Source Ref. No.",
        0, false, TempWarehouseActivityLine));

    if QtyReservedForCurrLine = 0 then
        exit;

    ReservEntry.SetSourceFilter(
                             TempTrackingSpecification2."Source Type", TempTrackingSpecification2."Source Subtype",
                             TempTrackingSpecification2."Source ID", TempTrackingSpecification2."Source Ref. No.", true);
    ReservEntry.SetSourceFilter('', TempTrackingSpecification2."Source Prod. Order Line");
    ReservEntry.SetRange("Reservation Status", ReservEntry."Reservation Status"::Surplus);
    if not ReservEntry.FindSet() then
        exit;

    ReservEntry.CalcSums("Qty. to Handle (Base)");
    SurplusQtyToHandle := Abs(ReservEntry."Qty. to Handle (Base)");
    if (QtyReservedForCurrLine + SurplusQtyToHandle) < SalesLine."Qty. to Ship (Base)" then
        exit;
      
     ReservEntry.ModifyAll("Qty. to Handle (Base)", 0);
     ReservEntry.ModifyAll("Qty. to Invoice (Base)", 0);


end;

`

Describe the request

Add a new event at the end of procedure "SyncSurPlusItemTracking" in the Codeunit 80 "Sales-Post" to skip the execution of the "ModifyAll".

`

           local procedure SyncSurPlusItemTracking(SalesHeader: Record "Sales Header"; SalesLine: Record "Sales Line")
var
    Location2: Record Location;
    ReservEntry: Record "Reservation Entry";
    TempTrackingSpecification2: Record "Tracking Specification" temporary;
    TempWarehouseActivityLine: Record "Warehouse Activity Line" temporary;
    WarehouseAvailabilityMgt: Codeunit "Warehouse Availability Mgt.";
    QtyReservedForCurrLine: Decimal;
    SurplusQtyToHandle: Decimal;
    IsHandled: Boolean;
begin
    if not SalesHeader.Ship then
        exit;
    if not (SalesHeader."Document Type" in [SalesHeader."Document Type"::Invoice, SalesHeader."Document Type"::Order]) then
        exit;

    if (SalesLine."Location Code" = '') or
       not Location2.Get(SalesLine."Location Code") or
       not Location2."Require Shipment"
    then
        exit;

    TempTrackingSpecification2.SetSourceFromSalesLine(SalesLine);
    QtyReservedForCurrLine := Abs(WarehouseAvailabilityMgt.CalcLineReservedQtyOnInvt(
        TempTrackingSpecification2."Source Type", TempTrackingSpecification2."Source Subtype", TempTrackingSpecification2."Source ID", TempTrackingSpecification2."Source Ref. No.",
        0, false, TempWarehouseActivityLine));

    if QtyReservedForCurrLine = 0 then
        exit;

    ReservEntry.SetSourceFilter(
                             TempTrackingSpecification2."Source Type", TempTrackingSpecification2."Source Subtype",
                             TempTrackingSpecification2."Source ID", TempTrackingSpecification2."Source Ref. No.", true);
    ReservEntry.SetSourceFilter('', TempTrackingSpecification2."Source Prod. Order Line");
    ReservEntry.SetRange("Reservation Status", ReservEntry."Reservation Status"::Surplus);
    if not ReservEntry.FindSet() then
        exit;

    ReservEntry.CalcSums("Qty. to Handle (Base)");
    SurplusQtyToHandle := Abs(ReservEntry."Qty. to Handle (Base)");
    if (QtyReservedForCurrLine + SurplusQtyToHandle) < SalesLine."Qty. to Ship (Base)" then
        exit;
      

    // New Event with IsHandled

       OnBeforeModifyQtyToHandleInvoiceOnAfterSyncSurPlusItemTracking(SalesLine, SalesHeader, IsHandled, ReservEntry);

      if not IsHandled then begin
             
             ReservEntry.ModifyAll("Qty. to Handle (Base)", 0);
             ReservEntry.ModifyAll("Qty. to Invoice (Base)", 0);
    end;

end;

`

`

      [IntegrationEvent(false, false)]
local procedure OnBeforeModifyQtyToHandleInvoiceOnAfterSyncSurPlusItemTracking(SalesLine: Record "Sales Line"; SalesHeader: Record "Sales Header"; var IsHandled: Boolean; var ReservEntry: Record "Reservation Entry")
begin
end;

`
Internal work item: AB#626145

[AleksandricMarko]

Hi Mariangela De Maio (@Mariangela-DeMaio-EOS),

Thanks for submitting this extensibility request. To help us process it efficiently, please update the issue to include the required information.

📚 Extensibility Guidelines

Missing Information:

• Alternatives Evaluated: Please explain which existing events or extensibility patterns you evaluated and why they are insufficient. For example, are there any existing events in Codeunit 80 "Sales-Post" that could be used? Why won't a standard event (without IsHandled) work?

• Justification for IsHandled: While your business need is clear, please explain why specifically an IsHandled event is required. Why wouldn't a standard integration event (without the ability to skip code) work for your scenario?

• Performance Considerations: Please assess the expected execution frequency of this procedure and the potential performance impact of the event. How often is SyncSurPlusItemTracking called during sales posting?

• Data Sensitivity Review: Please confirm whether the ReservEntry record being passed to subscribers contains any sensitive data that extensions should not access.

• Multi-Extension Interaction: Please discuss the risks if multiple extensions subscribe to this IsHandled event. What happens if multiple extensions attempt to set IsHandled := true? How should conflicts be handled?

Please update the issue with the missing details. We'll automatically re-analyze once updated.

[Mariangela-DeMaio-EOS]

Hi Marko Aleksandric (@AleksandricMarko),
thanks for your quick reply.
I will try to answer.

Alternatives Evaluated: To fix the issue, as an alternative we would need to save the quantities — which get zeroed out — into another field of the reservation entry or into a codeunit single instance, and use two standard events: one before the procedure SyncSurPlusItemTracking to save them, and another event at the end to restore the quantities. This approach is not performant and it is not guaranteed that the SyncSurplusItemTracking procedure will actually be executed, because the preceding standard events have IsHandled and someone else could use it and exit before SyncSurplusItemTracking runs.
Our app has been published for 5 years and used by many customers, the problem arises now because the procedure was recently added in version BC 27.2
Actually, I didn't understand its purpose and I didn't find a way, using Business central, to get to the end of the procedure and therefore to the ModifyAll part.
It would be helpful to know why it was added.

Justification for IsHandled: Without the IsHandled parameter, the standard code modifies the reservation entries and then we would need to restore the quantities afterwards, so we have to redo the modify.
However, we need to save the quantities before restoring them.
This would be pointless and not performant.

Performance Considerations: the procedure SyncSurPlusItemTracking is executed once per sales order header when posting the warehouse shipment.

Data Sensitivity Review: the record ReservEntry doesn’t contain sensitive data.

Multi-Extension Interaction: Our app has its logic, we don’t always have to skip the ModifyAll and we can know if the surplus reservation entries were created by our app.
I can't know what others will do with the IsHandled parameter but I don't think that other logics can conflict with ours .

[AleksandricMarko]

✅ Analysis complete - approved for implementation

---

Implementation:

Add integration event OnSyncSurPlusItemTrackingOnBeforeModifyQtyToHandleInvoice with IsHandled pattern in the SyncSurPlusItemTracking procedure of Codeunit 80 "Sales-Post", positioned before the ModifyAll operations.

Location in SyncSurPlusItemTracking procedure (around line 11950):

if (QtyReservedForCurrLine + SurplusQtyToHandle) < SalesLine."Qty. to Ship (Base)" then
    exit;

IsHandled := false;
OnSyncSurPlusItemTrackingOnBeforeModifyQtyToHandleInvoice(SalesLine, SalesHeader, IsHandled, ReservEntry);  // <-- New event
if IsHandled then
    exit;

ReservEntry.ModifyAll("Qty. to Handle (Base)", 0);
ReservEntry.ModifyAll("Qty. to Invoice (Base)", 0);

Event Publisher (add at the end of the codeunit with other events):

[IntegrationEvent(false, false)]
local procedure OnSyncSurPlusItemTrackingOnBeforeModifyQtyToHandleInvoice(SalesLine: Record "Sales Line"; SalesHeader: Record "Sales Header"; var IsHandled: Boolean; var ReservationEntry: Record "Reservation Entry")
begin
end;

---

File: SalesPost.Codeunit.al

Implementation Notes:

1. Add IsHandled: Boolean; variable declaration at the beginning of the procedure
2. Always initialize IsHandled := false; before calling the event
3. Parameter name changed to ReservationEntry (not ReservEntry) per naming convention

[JesperSchulz]

Thanks for reporting this. We agree, and we’ll publish a fix asap, either in an update for the current version or in the next major release. Please do not reply to this, as we do not monitor closed issues. If you have follow-up questions or requests, please create a new issue where you reference this one.

Build ID: 48589.